void drawHelp() {
  pushStyle();
  fill(200,200,200,255);
  textAlign(LEFT);
  rectMode(CORNER);
  rect(20, 30, w*0.55, w*0.90);
  fill(255,0,0);  
  textSize(18);
  textAlign(CENTER);
  text("CONTEXT", w*0.55/2,50);
  textSize(w/25);
  textAlign(LEFT);
  fill(0);
  String infos = "";
  infos += " PARAMETERS \n";
  infos += " cells       : "+str(S)+"\n";
  infos += " particles: "+str(Np)+"\n";
  infos += " viscosity: "+str(visc)+"\n";
  infos += " diffusion: "+str(diff)+"\n";
  infos += " dt step    : "+str(dt)+"\n";
  
  infos += " CONTROLS \n";
  infos += " Left-MB to add forces \n Right-MB to add density \n";
  infos += " s: add a source \n";
  infos += " v: show/hide velocity field \n";
  infos += " d: show/hide density field \n";
  infos += " g: show/hide grid \n";
  infos += " p: show/hide particles \n";
  infos += " q: add solid cell \n"; 
  infos += " r: restore all \n";   
  infos += " h: show/hide context \n";  
  text(infos, 30,80);
  popStyle();
}

//////////////////////////////////////////////////////////////////////////////////////////

void drawSolid(float h, boolean[] fluid) {
  pushStyle();
  for (int k=0; k<S; k++) {
    if (fluid[k]==false) {
      int[] t = XI(k);
      int i = t[0];
      int j = t[1];
      stroke(150);
      fill(150);
      rect(i*h,j*h,h,h);
    }
  }
  popStyle();
}

//////////////////////////////////////////////////////////////////////////////////////////

void drawGrid(float h) {
  pushStyle();
  noFill();
  stroke(0, 255, 255, 50);
  // GRID TRANSLATION
  float x0 = 0;
  float y0 = 0;
  // DRAW GRID
  for (int i=0; i<N+2; i++) {
    line(x0+i*h, y0, x0+i*h, y0+height);
    line(x0, y0+i*h, x0+width, y0+i*h);
  }
  popStyle();
}

//////////////////////////////////////////////////////////////////////////////////////////

void drawVelocity(float h, float[] vx, float[] vy, float scale) {
  // GRID TRANSLATION
  float x0 = -h/2;
  float y0 = -h/2; 
  // SPEED SCALE
  if (scale<=0) scale=1;
  stroke(255);
  for (int i=0; i<N+2; i++) {
    for (int j=0; j<N+2; j++) {
      // VELOCITY VECTOR OF EACH CELL
      float vmag = map(mag(vx[IX(i, j)],vy[IX(i, j)]), 0, 5, 0, 255);
      stroke(vmag, 0, 255-vmag);
      line(x0+i*h, y0+j*h, x0+i*h+scale*vx[IX(i, j)], y0+j*h+scale*vy[IX(i, j)]);
    }
  }
}

//////////////////////////////////////////////////////////////////////////////////////////

void drawDensity(float h, float[] dens) {
  pushStyle();
  // GRID TRANSLATION
  float x0 = 0;
  float y0 = 0;
  noStroke();
  for (int i=0; i<N+2; i++) {
    for (int j=0; j<N+2; j++) {
      float R = map(dens[IX(i,j)],0,30, 0,255);
      float G = map(dens[IX(i,j)],0,80, 0,255);
      float B = map(dens[IX(i,j)],0,200, 0,255);
      float A = map(dens[IX(i,j)],0,255, 0,255);      
      fill(R,G,B,255);
      rect(x0+i*h, y0+j*h, h, h);
    }
  }
  popStyle();
}